利用XSL和ASP在線編輯XML文檔(2)_Xml教程
教程Tag：暫無Tag,歡迎添加,賺取U幣!
推薦：簡單的XML操作：XML文件創建簡單的XML操作：XML文件創建 把下面的代碼復制到按鈕事件中編譯執行后可在相應物理路徑中產生Pos.xml文件 以下為引用的內容： XmlTextWriter xtw = ne
<%'---------------------------------
'定義函數 loadXMLFile(),接收二個參數：
'strXMLFile - XML 文件的路徑和文件名字
'strXSLFilee - XSL 文件的路徑和文件名字
'-------------------------------------
Function loadXMLFile(strXMLFile, strXSLFile)
'Declare local variables
Dim objXML
Dim objXSL
'實例化 XMLDOM 對象，以便載入 XML 文件。
set objXML = Server.CreateObject("Microsoft.XMLDOM")
'關掉文件異步載入模式。
objXML.async = false
'載入 XML 文件！
objXML.load(strXMLFile)
'實例化 XMLDOM 對象，以便載入 XSL 文件。
set objXSL = Server.CreateObject("Microsoft.XMLDOM")
'關掉文件異步載入模式。
objXSL.async = false
'載入 XSL 文件！
objXSL.load(strXSLFile)
'利用 XMLDOM 的 transformNode 方法，把 XSL 樣式表應用到 XML 文檔，然后輸出到客戶端。
Response.Write(objXML.transformNode(objXSL))
End Function
'----------------------------------------
'函數 updateXML() 接收一個參數：strXMLFile - XML 文件的路徑和文件名。
'----------------------------------------
Function updateXML(strXMLFile)
'聲明局部變量。
Dim objDom
Dim objRoot
Dim objField
Dim x
'實例化 XMLDOM 對象。
set objDOM = Server.CreateObject("Microsoft.XMLDOM")
'關掉文件異步載入模式。
objDOM.async = false
'載入 XML 文件。
objDOM.load strXMLFile
'設定根元素。
Set objRoot = objDom.documentElement
'遍歷 FORM 集合，并把提交的數據寫入 XML 文件。
For x = 1 to Request.Form.Count
'檢查提交的數據是否包含按鈕。如果是，忽略此數據。
If instr(1,Request.Form.Key(x),"btn") = 0 Then
'按照 XSL 查詢模式，建立 objField 變量，把表單的元素對應到 XML 文檔里的相應元素[field_value]。
Set objField = objRoot.selectSingleNode("field[@id='" & Request.Form.Key(x) & "']/field_value")
'把表單提交的數據和 XML 文檔里的節點值對應起來。
objField.Text = Request.Form(x)
End If
Next
'保存編輯過的 XML 文件。
objDom.save strXMLFile
'釋放所有對對象的引用。
Set objDom = Nothing
Set objRoot = Nothing
Set objField = Nothing
'調用 loadXMLFile 函數，把新編輯后的 XML 文件用 updateduserdata.xsl 樣式單顯示到客戶端。
loadXMLFile strXMLFile,server.MapPath("updateduserdata.xsl")
End Function
'檢查表單是否成功提交，如提交，更新 XML 文件；否則，轉到編輯狀態。
If Request.Form("btnSubmit") = "" Then
loadXMLFile server.MapPath("userdata.xml"),server.MapPath("userdata.xsl")
Else
updateXML server.MapPath("userdata.xml")
End If
%>
分享：獲取mssql的xml返回結構的方法數據庫在時回加for xml auto 調用方法 SqlCommand SqlComm= new SqlCommand("Psp_ShowMarkerProduct",Db.SqlConn); XmlReader Xr= SqlComm.ExecuteXmlReader();
相關Xml教程：
- 相關鏈接：
- 教程說明：
Xml教程-利用XSL和ASP在線編輯XML文檔(2)
。