如何向XML文件存儲數據_Xml教程
      
編輯Tag賺U幣
      


      教程Tag：暫無Tag,歡迎添加,賺取U幣!
      


      

      推薦：淺析XML教程之XML DHTML 行為
      Internet Explorer 5引入了DHTML行為。行為（Behaviors）是一種借助CSS的便利性向HTML元素添加DHTML功能性的方法。 行為 - 什么是行為? IE 5引入了DHTML行為（DHTML behaviors）。行為（Behaviors）是一種借助CSS的便利性向HTML元素添加DHTML功能性的方法。
      通常，我們在數據庫中存儲數據。不過，如果希望數據的可移植性更強，我們可以把數據存儲XML文件中。
      創建并保存XML文件
      如果數據要被傳送到非Windows平臺上的應用程序，那么把數據保存在XML文件中是有好處的。請記住，XML有很強的跨平臺可移植性，并且數據無需轉換！
      首先，我們將學習如何創建并保存一個XML文件。下面的這個XML文件將被命名為"test.xml"，并被保存在服務器上的c目錄中。我們將使用ASP和微軟的XMLDOM對象來創建并保存這個XML文件：
      <%
Dim xmlDoc, rootEl, child1, child2, p
'創建XML文檔
Set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")
'創建根元素并將之加入文檔
Set rootEl = xmlDoc.createElement("root")
xmlDoc.appendChild rootEl
'創建并加入子元素
Set child1 = xmlDoc.createElement("child1")
Set child2 = xmlDoc.createElement("child2")
rootEl.appendChild child1
rootEl.appendChild child2
'創建 XML processing instruction
'并把它加到根元素之前
Set p=xmlDoc.createProcessingInstruction("xml","version='1.0'")
xmlDoc.insertBefore p,xmlDoc.childNodes(0)
'把文件保存到c目錄
xmlDoc.Save "c:\test.xml"
%>
      如果您打開這個被保存的文件，它會使這個樣子("test.xml")：
      <?xml version="1.0"?>
<root>
  <child1 />
  <child2 />
</root>
      真實的表單例子
      現在，我們看一個真實的表單例子。
      我們首先看一下這個被用在例子中的HTML表單：下面的HTML表單要求用戶輸入他們的名字、國籍以及電子郵件地址。隨后這些信息會被寫到一個XML文件，以便存儲。
      "customers.htm":
      <html>
<body>
<form action="saveForm.asp" method="post">
<h1>請輸入您的聯系信息：</h1>
<label>名字: </label>
<p><input type="text" id="fname" name="fname"></p>
<label>姓氏: </label>
<p><input type="text" id="lname" name="lname"></p>
<label>國家: </label>
<p><input type="text" id="country" name="country"></p>
<label>郵件: </label>
<p><input type="text" id="email" name="email"></p>
<p>
<input type="submit" id="btn_sub" name="btn_sub" value="Submit">
<input type="reset" id="btn_res" name="btn_res" value="Reset">
</p>
</form>
</body>
</html>
      用于以上HTML表單的action被設置為"saveForm.asp"。"saveForm.asp"文件是一個ASP頁面，可循環遍表單域，并把它們的值存儲在一個XML文件之中：
      <%
dim xmlDoc
dim rootEl,fieldName,fieldValue,attID
dim p,i
'如果有錯誤發生，不允許程序終止
On Error Resume Next
Set xmlDoc = server.CreateObject("Microsoft.XMLDOM")
xmlDoc.preserveWhiteSpace=true
'創建并向文檔添加根元素
Set rootEl = xmlDoc.createElement("customer")
xmlDoc.appendChild rootEl
'循環遍歷Form集
for i = 1 To Request.Form.Count
  '除去表單中的button元素
  if instr(1,Request.Form.Key(i),"btn_")=0 then
    '創建field 和 value 元素，以及　id 屬性
    Set fieldName = xmlDoc.createElement("field")
    Set fieldValue = xmlDoc.createElement("value")
    Set attID = xmlDoc.createAttribute("id")
    '把當前表單域的名稱設置為id屬性的值
    attID.Text = Request.Form.Key(i)
    '把id屬性添加到field元素
    fieldName.setAttributeNode attID
    '把當前表單域的值設置為value元素的值
    fieldValue.Text = Request.Form(i)
    '將field元素作為根元素的子元素進行添加
    rootEl.appendChild fieldName
    '將value元素作為field元素的子元素進行添加
    fieldName.appendChild fieldValue
  end if
next
'添加XML processing instruction
'并把它加到根元素之前
Set p = xmlDoc.createProcessingInstruction("xml","version='1.0'")
xmlDoc.insertBefore p,xmlDoc.childNodes(0)
'保存XML文件
xmlDoc.save "c:\Customer.xml"
'釋放所有的對象引用
set xmlDoc=nothing
set rootEl=nothing
set fieldName=nothing
set fieldValue=nothing
set attID=nothing
set p=nothing
'測試是否有錯誤發生
if err.number<>0 then
  response.write("Error: No information saved.")
else
  response.write("Your information has been saved.")
end if
%>
      注釋：如果被指定的XML文件名已經存在，那個文件會被覆蓋！
      XML文件會由上面的代碼生成，大致的樣子是這樣的：("Customer.xml"):
      <?xml version="1.0" ?>
<customer>
  <field id="firstName">
    <value>Hege</value> 
  </field>
  <field id="lastName">
    <value>Refsnes</value> 
  </field>
  <field id="country">
    <value>Norway</value> 
  </field>
  <field id="email">
    <value>mymail@myaddress.com</value> 
  </field>
</customer>
       
      分享：解析關于XSL的基礎知識
      什么是XSL 全稱Extensible Style Language，中文譯作擴展樣式語言，用于格式化XML文檔,它由兩部分組成. 1（XSLT ）:XSL Transformation Language(XSLT),它可以把XML文檔從一種格式轉化為另一種格式.如轉成html,文本或是基于文本的文檔. 2（ XPath）:XSL格式
      


      

      


      來源：模板無憂//所屬分類：Xml教程/更新時間：2010-01-30


      


      



      


      



      相關Xml教程：